1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
|
// To keep this in the first portion of the binary.
.section ".text.boot"
// Make _start global.
.globl _start
_start:
reset:
// disable core0,1,2.
mrc p15, #0, r1, c0, c0, #5
and r1, r1, #3
cmp r1, #0
bne io_halt
// set vector address.
ldr r0, =vector
mcr p15, 0, r0, c12, c0, 0
// save cpsr.
mrs r0, cpsr
// setup sp in IRQ mode.
bic r1, r0, #0x1f
orr r1, r1, #0x12
msr cpsr_c,r1
mov sp,#0x4000
// restore cpsr.
msr cpsr_c, r0
// setup the stack in SVC mode.
mov sp, #0x8000
// Clear out bss.
ldr r4, =__bss_start
ldr r9, =__bss_end
mov r5, #0
mov r6, #0
mov r7, #0
mov r8, #0
b 2f
1:
// store multiple at r4.
stmia r4!, {r5-r8}
// If we are still below bss_end, loop.
2:
cmp r4, r9
blo 1b
// Call kernel_main
ldr r3, =kernel_main
blx r3
irq:
push {r0,r1,r2,r3,r4,r5,r6,r7,r8,r9,r10,r11,r12,lr}
cpsid i
bl c_irq_handler
cpsie i
pop {r0,r1,r2,r3,r4,r5,r6,r7,r8,r9,r10,r11,r12,lr}
subs pc, lr, #4
.globl io_halt
io_halt:
wfi
b io_halt
io_halt_undefined:
stmfd sp!, {r0-r12,lr}
ldr r0, [lr, #-8]
push {r0}
ldr r0, =undefined_msg
bl uart_string
pop {r0}
bl uart_hexn
// Skip instruction for now
// In future,
// ldmfd ... pc->lr
// subs pc, lr, #8
ldmfd sp!, {r0-r12,pc}^
io_halt_swi:
stmfd sp!, {r0-r12,lr}
ldr r0, [lr, #-4]
bic r0, #0xFF000000
push {r0}
ldr r0, =swi_msg
bl uart_string
pop {r0}
bl uart_hexn
ldmfd sp!, {r0-r12,pc}^
io_halt_prefetch:
ldr r0, =prefetch_msg
push {lr}
bl uart_string
pop {lr}
b io_halt
io_halt_data:
ldr r0, =data_msg
push {lr}
bl uart_string
pop {lr}
b io_halt
io_halt_unused:
ldr r0, =unused_msg
push {lr}
bl uart_string
pop {lr}
b io_halt
io_halt_fiq:
ldr r0, =fiq_msg
push {lr}
bl uart_string
pop {lr}
b io_halt
.align 5
vector:
ldr pc, reset_handler
ldr pc, undefined_handler
ldr pc, swi_handler
ldr pc, prefetch_handler
ldr pc, data_handler
ldr pc, unused_handler
ldr pc, irq_handler
ldr pc, fiq_handler
reset_handler: .word reset
undefined_handler: .word io_halt_undefined
swi_handler: .word io_halt_swi
prefetch_handler: .word io_halt_prefetch
data_handler: .word io_halt_data
unused_handler: .word io_halt_unused
irq_handler: .word irq
fiq_handler: .word io_halt_fiq
.section .data
undefined_msg: .asciz "Undefined Handler\n"
swi_msg: .asciz "SWI Handler\n"
prefetch_msg: .asciz "Prefetch Handler\n"
data_msg: .asciz "Data Handler\n"
unused_msg: .asciz "Unused Handler\n"
fiq_msg: .asciz "FIQ\n"
|
